// SPDX-FileCopyrightText: 2022 Paul Schaub <vanitasvitae@fsfe.org>
//
// SPDX-License-Identifier: Apache-2.0

plugins {
    id 'application'
}

group 'org.pgpainless'

repositories {
    mavenCentral()
}

dependencies {
    // Testing
    testImplementation "org.junit.jupiter:junit-jupiter-api:$junitVersion"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junitVersion"

    // Logging
    implementation "org.slf4j:slf4j-api:$slf4jVersion"
    testImplementation "ch.qos.logback:logback-classic:$logbackVersion"

    // WKD and OpenPGP
    implementation project (":wkd-java")
    implementation "org.pgpainless:pgpainless-core:$pgpainlessVersion"

    // CLI
    implementation "info.picocli:picocli:4.6.3"

    // Object Mapping
    implementation 'com.fasterxml.jackson.dataformat:jackson-dataformat-xml:2.13.1'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.13.1'
}
mainClassName = 'pgp.wkd.test_suite.Main'

jar {
    duplicatesStrategy(DuplicatesStrategy.EXCLUDE)
    manifest {
        attributes 'Main-Class': "$mainClassName"
    }

    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    } {
        exclude "META-INF/*.SF"
        exclude "META-INF/*.DSA"
        exclude "META-INF/*.RSA"
    }
}

test {
    useJUnitPlatform()
}