mirror of
https://github.com/vanitasvitae/Smack.git
synced 2024-11-19 10:32:05 +01:00
3d4e7938a7
ExtensionElement is now a marker interface that requires all implementation non-abstract classes to carry a static final QNAME field (of type QName). This is verified by a new unit test. Also FullyQualifiedElement is renamed to simply XmlElement. XmlElement is used over ExtensionElement when implementing classes do not statically know the qualified name of the XML elements they represent. In general, XmlElement should be used sparingly, and every XML element should be modeled by its own Java class (implementing ExtensionElement).
51 lines
2.1 KiB
Groovy
51 lines
2.1 KiB
Groovy
description = """\
|
|
Full Smack library for Java SE."""
|
|
|
|
dependencies {
|
|
api project(':smack-bosh')
|
|
api project(':smack-debug')
|
|
api project(':smack-experimental')
|
|
api project(':smack-extensions')
|
|
api project(':smack-java8')
|
|
api project(':smack-legacy')
|
|
api project(':smack-omemo')
|
|
api project(':smack-openpgp')
|
|
api project(':smack-resolver-minidns')
|
|
api project(':smack-resolver-minidns-dox')
|
|
// TODO: Change this to smack-websocket-java11 once it arrives.
|
|
api project(':smack-websocket-okhttp')
|
|
api project(':smack-tcp')
|
|
|
|
testImplementation(testFixtures(project(":smack-core")))
|
|
testImplementation 'org.jgrapht:jgrapht-io:1.3.1'
|
|
testImplementation "org.reflections:reflections:${orgReflectionsVersion}"
|
|
}
|
|
|
|
task printModularXmppClientToServerConnectionStateGraph(type: JavaExec) {
|
|
classpath sourceSets.main.runtimeClasspath
|
|
main 'org.jivesoftware.smack.full.ModularXmppClientToServerConnectionTool'
|
|
}
|
|
|
|
task generateModularXmppClientToServerConnectionStateGraph(type: JavaExec) {
|
|
// TODO: Filter out all files which do not contain the String
|
|
// StateDescriptor.
|
|
inputs.files file('..').listFiles().findAll {it.name.endsWith('.java')}
|
|
outputs.files 'src/javadoc/org/jivesoftware/smack/full/doc-files/ModularXmppClientToServerConnectionStateGraph.dot'
|
|
classpath sourceSets.main.runtimeClasspath
|
|
main 'org.jivesoftware.smack.full.ModularXmppClientToServerConnectionTool'
|
|
args outputs.files
|
|
}
|
|
|
|
task convertModularXmppClientToServerConnectionStateGraphDotToPng(type: Exec) {
|
|
dependsOn generateModularXmppClientToServerConnectionStateGraph
|
|
inputs.files 'src/javadoc/org/jivesoftware/smack/full/doc-files/ModularXmppClientToServerConnectionStateGraph.dot'
|
|
outputs.files 'src/javadoc/org/jivesoftware/smack/full/doc-files/ModularXmppClientToServerConnectionStateGraph.png'
|
|
|
|
executable 'dot'
|
|
args "-Tpng", "-o", "${outputs.files.first()}", "${inputs.files.first()}"
|
|
}
|
|
|
|
task cleanGenerateFiles(type: Delete) {
|
|
delete 'src/javadoc/org/jivesoftware/smack/full/doc-files/ModularXmppClientToServerConnectionStateGraph.dot', 'src/javadoc/org/jivesoftware/smack/full/doc-files/ModularXmppClientToServerConnectionStateGraph.png'
|
|
}
|
|
clean.dependsOn cleanGenerateFiles
|